Sports Illustrated for Kids - Awesome Athletes!/Sports Illustrated for Kids - Awesome Athletes!.iso/shared.dir/07005_UI Rollover.ls

Text File | 1996-04-18 | 4.8 KB | 176 lines

global goSIUIAsset

on UIInitMenu
  global gUIPoints, gUIInitMenu
  set gUIPoints to [:]
  addProp(gUIPoints, "-button", rect(574, 427, 640, 480))
  addProp(gUIPoints, "th", rect(503, 307, 593, 319))
  addProp(gUIPoints, "ma", rect(503, 320, 593, 333))
  addProp(gUIPoints, "tr", rect(503, 334, 593, 346))
  addProp(gUIPoints, "wd", rect(503, 347, 593, 359))
  addProp(gUIPoints, "sd", rect(503, 360, 593, 372))
  addProp(gUIPoints, "iv", rect(503, 373, 593, 385))
  addProp(gUIPoints, "hf", rect(503, 386, 593, 399))
  addProp(gUIPoints, "-options", rect(503, 400, 593, 412))
  addProp(gUIPoints, "-help", rect(503, 413, 573, 426))
  addProp(gUIPoints, "-exit", rect(503, 427, 573, 438))
  set gUIInitMenu to 1
  set goSIUIAsset to birth(script "AssetManager", 7431)
end

on UIMenu
  global gUIPoints, gUIInitMenu, gSICurrMovie
  if not gUIInitMenu then
    UIInitMenu()
  end if
  set vSprite to the clickOn
  set vSaveCast to the castNum of sprite vSprite
  set vSaveX to the locH of sprite vSprite
  set vSaveY to the locV of sprite vSprite
  puppetSprite(vSprite, 1)
  set the locH of sprite vSprite to 604
  set the locV of sprite vSprite to 450
  set the ink of sprite vSprite to 8
  set vOrgPoint to point(the mouseH, the mouseV)
  set vDone to 0
  set vLastCast to EMPTY
  set vDown to 1
  set vFirstTime to 1
  set vDownMode to 0
  repeat while not vDone
    set vMouse to point(the mouseH, the mouseV)
    set vItem to 0
    repeat with vI = 1 to 11
      if inside(vMouse, getAt(gUIPoints, vI)) then
        set vItem to vI
        exit repeat
      end if
    end repeat
    set vWasDown to vDown
    set vDown to the mouseDown
    if (vItem = 0) or (vItem = 1) then
      set vCastName to gSICurrMovie & "-UI-NONE"
    else
      set vCastName to gSICurrMovie & "-UI-" & integer(vItem - 1) & "-ROLLOVER"
    end if
    if vLastCast <> vCastName then
      set vLastCast to vCastName
      set the castNum of sprite vSprite to mGetAssetNo(goSIUIAsset, vCastName)
      updateStage()
    end if
    if vDownMode then
      if vDown then
        set vDone to 1
      end if
      next repeat
    end if
    if vWasDown and not vDown then
      if vItem = 1 then
        set vDownMode to 1
        next repeat
      end if
      set vDone to 1
    end if
  end repeat
  set the castNum of sprite vSprite to cast (gSICurrMovie & "-UI")
  set the locH of sprite vSprite to vSaveX
  set the locV of sprite vSprite to vSaveY
  puppetSprite(vSprite, 0)
  updateStage()
  if vItem > 0 then
    set vModule to getPropAt(gUIPoints, vItem)
    if char 1 of vModule = "-" then
      if vModule = "-options" then
        LaunchOptions()
      else
        if vModule = "-help" then
          LaunchHelp()
        else
          if vModule = "-exit" then
            exitApp()
          end if
        end if
      end if
    else
      navGoTo(vModule)
    end if
  end if
end

on UIPress
  global gUILastSprite
  set vSprite to the clickOn
  set vCastNo to the castNum of sprite vSprite
  set vCastNam to the name of cast vCastNo
  puppetSprite(vSprite, 1)
  if (vCastNam = 0) or (vCastNam = EMPTY) then
    set the castNum of sprite vSprite to vCastNo + 1
  else
    if vCastNam contains "ROLLOVER" then
      set the castNum of sprite vSprite to vCastNo + 1
    else
      set the castNum of sprite vSprite to the number of cast (vCastNam & "-down")
    end if
  end if
  updateStage()
  repeat while the stillDown
    nothing()
  end repeat
  if (vCastNam = 0) or (vCastNam = EMPTY) then
    set the castNum of sprite vSprite to vCastNo
  else
    set the castNum of sprite vSprite to the number of cast vCastNam
  end if
  puppetSprite(vSprite, 0)
  updateStage()
  dontPassEvent()
  if the mouseCast = the castNum of sprite vSprite then
    return 1
  else
    return 0
  end if
end

on UIRollover aGoBack, aUI
  global gUILastSprite
  set vNowSprite to 0
  if aGoBack <> -1 then
    if rollOver(aGoBack) then
      set vNowSprite to aGoBack
    end if
  end if
  if aUI <> -1 then
    if rollOver(aUI) then
      set vNowSprite to aUI
    end if
  end if
  if vNowSprite <> 0 then
    set vCastNo to the castNum of sprite vNowSprite
    set vCastName to the name of cast vCastNo
    if vCastName contains "DOWN" then
      set vNowSprite to 0
    end if
  end if
  if vNowSprite = 0 then
    puppetSprite(gUILastSprite, 0)
    set gUILastSprite to 0
  else
    UIRollOverOn(vNowSprite)
    set gUILastSprite to vNowSprite
  end if
end

on UIRollOverOn vNowSprite
  global gUILastSprite
  if not (gUILastSprite = vNowSprite) then
    set vCastNo to the castNum of sprite vNowSprite
    set vCastNam to the name of cast vCastNo
    puppetSprite(vNowSprite, 1)
    if not (vCastNam contains "-ROLLOVER") then
      set the castNum of sprite vNowSprite to cast (vCastNam & "-ROLLOVER")
      updateStage()
    end if
    puppetSprite(gLastSprite, 0)
  end if
end